BarneyBlog

In the theme of URL shorteners, I whipped up some simple base conversion functions that don't have the hard limit of 36 that the inputBaseN and formatBaseN built-ins do, but otherwise are exact replacements.  Everything is controlled by the first line, the list of digits.  The functions will support whatever base you want, as long as you can supply enough unique digits.  Note that not all characters are valid on the URL, so for URL shortening you have to be somewhat careful what you pick.

The digit list below is 62 long.  You could add underscore, dash, period, plus, exclamation point, asterisk, apostrophe, left paren, right paren and comma to the list with relative safety, bringing the max base up to 72 URL-safe digits.  Depending on your webspace manager, you might be able to add slash and backslash.  And if you don't care about URLs, just shortening something, you can add pretty much anything.

Both functions will return the string "NaN" for an unsupported (too large or too small) base or an invalid number.   This is because I wrote them in CFSCRIPT and when I went to add bound checking I realized there still isn't a 'throw' statement in CFSCRIPT so I punted.  Write to Adobe.

The code should run on any CFML engine that supports CFSCRIPT UDFs.  I tested on either CF8 or Railo 3, but I'm not sure which.

digits = "0123456789abcdefghijklmnopqrstuvwxyzABCDEFGHIJKLMNOPQRSTUVWXYZ";
function decimalToBase(num, base) {
    var result = "";
    if (base LT 2 OR base GT len(digits)) {
        return "NaN";
    }
    result = mid(digits, num MOD base + 1, 1);
    while (num GT base) {
        num = num / base;
        result = mid(digits, num MOD base + 1, 1) & result;
    }
    return result;
}
function baseToDecimal(num, base) {
    var result = 0;
    var digit = "";
    var pos = "";
    if (base LT 2 OR base GT len(digits)) {
        return "NaN";
    }
    while (len(num) GT 0) {
        digit = left(num, 1);
        num = removeChars(num, 1, 1);
        pos = find(digit, digits);
        if (pos LTE 0) {
            return "NaN";
        }
        result = result + (pos - 1) * base ^ len(num);
    }
    return result;
}

Joshua, Koen and I were discussing URL shortening services (tinyurl, bit.ly, is.gd, etc.) over lunch this week, and so I decided to write my own (UrlShrink) available here: http://www.barneyb.com/applications/urlshrink/app/

It's ludicriously simple.  I opted for memory storage (think Mailinator) instead of a database for performance reasons.  With the load I anticipate, I think it'll be a deciding factor.  I've also included stable URL generation (which I don't know that any other service does), so if you try to shorten the same URL repeatedly, you'll get the same result every time.  As well as being more user friendly, this further increases performance because it prevents artificial bloat to the keyspace, thereby making searches marginally faster.

The app is all CFML, aside from an Alias and couple RewriteRules to make the URLs pretty.  Here are the rules:

Alias   /applications/urlshrink/app /home/www/urlshrink
RewriteRule ^(/applications/urlshrink/app)/geturl   $1/geturl.cfm   [PT]
RewriteRule ^(/applications/urlshrink/app)/shorturl/([^/]*) $1/forward.cfm?key=$2   [PT]

And here's the CFML (in five files) in case anyone else is interested in running their own service:

Application.cfm:
----------------
<cfapplication name="urlshrink" sessionmanagement="false" />
<cfset urlRoot = "http://www.barneyb.com/applications/urlshrink/app" />
<cfif NOT structKeyExists(application, "forwardLookup")>
        <cfset application.forwardLookup = {} />
        <cfset application.reverseLookup = {} />
</cfif>

index.cfm:
----------
<cfoutput>
<h1>UrlShrink</h1>
</cfoutput>
<cfinclude template="frm_shrink.cfm" />

frm_shrink.cfm:
---------------
<cfoutput>
<p>To make a shorter URL, just paste your long URL here and hit "Go!".
</p>
<form method="post" action="#urlRoot#/geturl">
URL:
<input name="url" size="50" />
<input type="submit" value="Go!" />
</form>
</cfoutput>

geturl.cfm:
-----------
<cfif structKeyExists(application.reverseLookup, form.url)>
        <cfset key = application.reverseLookup[form.url] />
        <cfset newUrl = urlRoot & "/shorturl/" & key />
<cfelse>
        <cfset key = hash(form.url, "SHA-256") />
        <cfset newUrl = urlRoot & "/shorturl/" & key />
        <cfif len(form.url) GT len(newUrl)>
                <cfset key = hash(form.url, "SHA-512") />
                <cfset newUrl = urlRoot & "/shorturl/" & key />
        </cfif>
        <cfset application.forwardLookup[key] = form.url />
        <cfset application.reverseLookup[form.url] = key />
</cfif>
<cfset percentSavings = -1 * (len(newUrl) - len(form.url)) / len(form.url) * 100 />
<cfoutput>
<h1>UrlShrink</h1>
<p>Your shortened URL is:
</p>
<p><a href="#newUrl#" style="white-space:nowrap;">#newUrl#</a>
</p>
<p>You've reduced the length of your URL by an exceptional #numberFormat(percentSavings, ".0")#%!
</p>
<h2>Shrink Another?</h2>
<cfinclude template="frm_shrink.cfm" />
</cfoutput>

forward.cfm:
------------
<cfparam name="url.key" default="" />
<cfif structKeyExists(url, "key") AND structKeyExists(application.forwardLookup, url.key)>
        <cflocation url="#application.forwardLookup[url.key]#" addtoken="false" />
<cfelse>
        <cfoutput>
        <h1>UrlShrink</h1>
        <p>The URL you're visiting isn't recognized.  Perhaps you'd like to shrink your own?
        </p>
        <cfinclude template="frm_shrink.cfm" />
        </cfoutput>
</cfif>

Total size is 1,901 bytes; that's pretty respectable for such a full-featured app.